Hand Wash Timer 3D parts

Hand Wash Timer 3D parts è l’ultimo articolo dedicato al progetto in cui puoi leggere come sono state disegnate le parti in 3D:

Hand Wash Timer mounted

Inoltre potrai comprendere quali parti stampare, o modificare per adattarle ad un tuo progetto.

Nell’articolo Hand Wash Timer hai letto che le parti da stampare in 3D sono 3:

  • la base che include il porta batterie ed elettronica;
  • il coperchio che ospita il pulsante di accensione ed il sensore PIR;
  • il poggia had wash timer per tenerlo diritto in prossimità del lavandino;

ovviamente l’ultima parte puoi evitare di stamparla se decidi di posizionare in altro modo il tuo  hand wash timer 3D parts.

Come è fatto l’hand wash timer 3D parts

Analizziamo una per una le parti che compongono il progetto.

 

Ricorda che tutte le parti 3D del progetto puoi trovarle condivise su thingiverse e che il progetto completo è condiviso su gitHub.

La Base

La prima stampa ti serve è la base che contiene al suo interno lo spazio per il porta batterie ( 4 x AA ), l’elettronica ( attiny85, neopixel ring 16, DC-DC step down ).

 

Base hand wash timer 3D parts

 

Il modello 3D della base, come degli altri componenti, è stato interamente realizzato con openScad co il codice seguente:

pirDiam=11;
$fn=96;

batteryHolderBase();


module batteryHolderBase() {
    difference() {
        translate([0,0,11]) cylinder(r=45,h=22,center=true);
        
        union() {
            hull() {
                translate([0,-38,(pirDiam+4)/2]) rotate([90,0,0]) cylinder(r=pirDiam/2,h=20,center=true);
                translate([0,-32,25]) rotate([90,0,0]) cylinder(r=(pirDiam/2)+2.5,h=33,center=true);
            }
            
            // holes
            translate([41*cos(30),-41*sin(30),10]) cylinder(r=1.7,h=40,center=true);
            translate([-41*cos(30),-41*sin(30),10]) cylinder(r=1.7,h=40,center=true);
            translate([0,41,10]) cylinder(r=1.7,h=40,center=true);
            
            translate([41*cos(30),-41*sin(30),1.4]) cylinder(r=3,h=5,center=true);
            translate([-41*cos(30),-41*sin(30),2.4]) cylinder(r=3,h=5,center=true);
            translate([0,41,2.4]) cylinder(r=3,h=5,center=true);
            
            
            translate([0,0,pirDiam+10]) NeoPixel();
            translate([0,0,pirDiam+10]) micro();
            translate([0,0,6]) batteryHolder();
        }
    }
}

module NeoPixel() {
	difference() {
		cylinder(r=25,h=3,center=true);
		cylinder(r=15,h=5,center=true);
	}
}

module micro() {
	cylinder(r=12,h=3,center=true);
	translate([0,-14,0]) cube([pirDiam+4,65,3],center=true);
}

module batteryHolder() {
	cube([64,60,20],center=true);
	
	hull() {
		translate([28,26,10]) cube([8,8,20],center=true);
		translate([-28,26,10]) cube([8,8,20],center=true);
	}
}

non commenterò il codice di disegno in quanto è abbastanza chiaro dal nome delle funzioni ( moduli ) che lo compongono.

Il risultato, rendering, del modello è simile al seguente:

hand wash timer 3D parts base openscad

Il coperchio o cover

Rappresenta la parte in cui sono alloggiati il micro switch on/off ed il sensore pir, per la parte elettronica:

hand wash timer 3D partes cover

ed in cui sono stati praticati i fori per vedere in modo chiaro il succedersi delle 16 luci realizzate con il neopixel ring.

Il codice della cover è il seguente:

pirDiam=11;
$fn=96;

cover();

module cover() {
    difference() {
        translate([0,0,11]) cylinder(r=45,h=12,center=true);
        translate([0,0,10]) cylinder(r=38,h=12,center=true);
        
        translate([0,-38,(pirDiam+4)/2]) cylinder(r=pirDiam/2,h=20,center=true);
            
        // holes
        translate([41*cos(30),-41*sin(30),9]) cylinder(r=1.7,h=10,center=true);
        translate([-41*cos(30),-41*sin(30),9]) cylinder(r=1.7,h=10,center=true);
        translate([0,41,9]) cylinder(r=1.7,h=10,center=true);
        
        for(a=[0:22.5:360]) {
            translate([18.92*cos(a),18.92*sin(a),9]) cylinder(r=1,h=20,center=true);
        }
        
        // power switch
        hull() {
            for(a=[30:5:60]) {
            translate([36*cos(-a),-36*sin(-a),10]) cylinder(r=7,h=12,center=true);
            }
        }
        hull(){
            translate([45*cos(-40),-45*sin(-40),11.5]) rotate([90,0,-45]) cylinder(r=2,h=12,center=true);
            
            translate([45*cos(-50),-45*sin(-50),11.5]) rotate([90,0,-45]) cylinder(r=2,h=12,center=true);
        }
    }
}

ed il risultato, o rendering, che puoi visualizzare dopo averlo scritto si presenta così:

hand wash timer 3D cover openscad

non ti resta che l’ultima parte: il poggia hand wash timer.

Il poggia hand wash timer 3D parts

Serve per appoggiare facilmente il tuo hand wash timer vicino al lavabo mentre ti lavi le mani:

hand wash timer holder openscad

il cui codice è il seguente:

$fn=96;

difference() {
    translate([31,0,0]) cube([30,90,30],center=true);

    cylinder(r=45,h=32,center=true);

    translate([38,37,0]) cylinder(r=7,h=32,center=true);
    translate([38,-37,0]) cylinder(r=7,h=32,center=true);
}

decisamente semplice da realizzare e che puoi modificare per adattarlo al posto su cui vuoi appoggiarlo.

Il video demo

Ecco il video demo del progetto:

Prima di inserire un commento, per favore, leggi il regolamento

Permanent link to this article: https://www.mauroalfieri.it/elettronica/hand-wash-timer-3d-parts.html

Lascia un commento

Your email address will not be published.

Questo sito usa Akismet per ridurre lo spam. Scopri come i tuoi dati vengono elaborati.