3D support vinpok

3D support vinpok l’ho realizzato in questi giorni in cui mi è arrivato il kickstarter in cui avevo investito alcuni mesi fa: il monitor vinpok 15″

 

Quando il monitor mi è stato consegnato ho trovato al suo interno tutto il materiale previsto nell’acquisto.

Per un mio errore nel richiedere il monitor 15″ l’unico supporto che mi è stato inviato è un sottile e fragile supporto in plastica che assolve davvero male alle sue funzioni.

Dopo sole 3 ore di utilizzo, causa leggerezza e forma esigua, non è più stato in grado di mantenere il monitor in posizione verticale e quest’ultimo continua a cadere con il rischio di rompersi.

E’ prevista la possibilità di acquistare, insieme al monitor vinpok 15″, un supporto/cover che protegge il monitor ed allo stesso tempo sembra essere più resistente.

Ma noi siamo maker e ci piace usare le nostre competenze per risolvere piccoli problemi come questo.

Hp quindi deciso di utilizzare oprnSCAD per diseganre la mia versione del 3D support vinpok.

Condivisione

Ho deciso di condividere l’intero progetto su thingiverse così che tu possa scaricarlo, adattarlo alle tue esigenze, stamparlo e usarlo con il tuo monitor.

Realizzazione del 3D support vinpok 

Per la realizzazione del tuo supporto puoi partire dal sostegno vero e proprio al monitor, io l’ho chiamato parte vericale (vert), come puoi leggere nel codice sotto:

3d supprt vinpok vertical

che in codice è scritto così:

module vert() {
	difference() {
		cube([15,30,15]);
		translate([2,-1,2]) cube([11,32,15]);
		translate([7.5,15,0]) cylinder(r=5.5,h=2,center=true,$fn=96); // magnete
	}
	difference() {
		union() {
			translate([13,0,0]) cube([2,30,60]); // alzata
			translate([15,15,62]) rotate([90,0,0]) cylinder(r=3,h=30,center=true,$fn=96); // cilindro alto
		}
		translate([10,-1,58]) cube([10,7,8]); // cubo alzata
		translate([10,24,58]) cube([10,7,8]); // cubo alzata
		translate([15,15,62]) rotate([90,0,0]) cylinder(r=1.4,h=30,center=true,$fn=96); // cilindro alto
	}
	
}

ossia da un cubo principale (15,30,15) puoi sottrarre un cubo leggermente inferiore ( 11,32,15 ) come dimensione in modo da formare una parte concava in cui poggerai il monitor.

il resto del modello è per creare una parte verticale ed un cilindro in cui triveranno posto le viti di rotazione.

Nota che il foro del cilindro ha un raggio 1.4mm ed usando una vite da 3mm potrai facilmente avvitarla senza romperlo ma usando quest’ultimo come punto di fissaggio.

Realizzazione del supporto obliquo

Perchè il 3D support vinpok lavori in modo corretto è necessario fornirgli una base ed un supporto di sostegno che contrasti la volontà del monitor di cadere 🙂

3d support vinpok obliquo

ho realizzato quindi una parte inclinata dotata sia in alto sia in basso si due cilindri che permettano di fissarlo da un lato alla parte verticale e dall’altro a quella che sarà la base del supporto stesso.

Ecco il codice per realizzare tale parte del modello:

module support() {
	difference() {
		union() {
			translate([15.5,0,63]) rotate([0,58.7,0]) cube([72,30,2]); // support
			translate([52,15,1]) rotate([90,0,0]) cylinder(r=3,h=30,center=true,$fn=96); // cilindro fondo
			translate([14.9,15,62]) rotate([90,0,0]) cylinder(r=3,h=30,center=true,$fn=96); // cilindro alto
		}
	translate([52,15,1]) rotate([90,0,0]) cylinder(r=1.6,h=40,center=true,$fn=96); // foro cilindro fondo
	translate([15,15,62]) rotate([90,0,0]) cylinder(r=1.6,h=40,center=true,$fn=96); // foro cilindro alto
	translate([10,5,58]) cube([10,20,8]); // cubo alzata
	translate([48,5,-3]) cube([10,20,8]); // cubo base
	}
}

la parte più complessa che devi affrontare è quella della rotazione che influisce sullo spostamento delle diverse componenti.

In questo esempio ti viene in aiuto la trigonometria che diventa fondamentale per calcolare le coordinate dei punti di intersezione.

Realizzazione della base

La realizzazione della base è più semplice delle altre due perché è tutta relaizzata in orizzontale e non comporta parti difficoltose da realizzare:

3d support vinpok base

il codice che ti permette di realizzarne una simile è il seguente:

module base() {
	difference() {
		union() {
			translate([0,0,-2]) cube([52,30,2]); // base
			translate([52,15,1]) rotate([90,0,0]) cylinder(r=3,h=30,center=true,$fn=96); // cilindro fondo
		}
		translate([48,-1,-3]) cube([10,7,8]); // cubo alzata
		translate([48,24,-3]) cube([10,7,8]); // cubo alzata
		translate([52,15,1]) rotate([90,0,0]) cylinder(r=1.4,h=30,center=true,$fn=96); // cilindro fondo
		
		translate([7.5,15,0]) cylinder(r=5.5,h=2,center=true,$fn=96); // magnete
	}
}

in cui ci sono solo il cubo di base (52,30,2) ed il cilindro che ti permette di fissare questa parte al supporto obliquo.

I restanti solidi servono ad ottenere:

  • gli incavi sul cilindro di fissaggio
  • la foratura da 1.4mm di raggio
  • la sede del magnete

e sono sottratti dalla forma principale.

Stampa 3D

il 3D support vinpok è stampato in PLA con la mia Delta Kossel250 ed ecco i componenti dopo la stampa:

3d support vinpok components

in cui vedi anche le parti che ti serviranno per assemblare il 3D support vinpok:

  • n.4 viti M3x10mm
  • n.2 magneti al neodimio 10mm x 0.5mm

i due magneti trovano posto nelle rispettive sedi:

3d support vinpok materials

il primo nella base del modello ed il secondo nella parte inferiore del pezzo che ospita il monitor.

Usando le viti monta i 3 pezzi tra loro:

3d support vinpok mounted

e quando avrai finito il montaggio potrai chiuderlo come segue:

3d support vinpok step 1

e man mano che i due pezzi si avvicinano:

3d support vinpok step 2

ed infine i due magneti faranno in modo che il supporto risulti montato:

3d support vinpok step 3

a questo punto sei pronto per usarlo con il tuo vinpok 15″.

3d support vinpok monitor

  • Questo sito ed i suoi contenuti è fornito "così com'è" e Mauro Alfieri non rilascia alcuna dichiarazione o garanzia di alcun tipo, esplicita o implicita, riguardo alla completezza, accuratezza, affidabilità, idoneità o disponibilità del sito o delle informazioni, prodotti, servizi o grafiche correlate contenute sul sito per qualsiasi scopo.
  • Ti chiedo di leggere e rispettare il regolamento del sito prima di utilizzarlo
  • Ti chiedo di leggere i Termini e Condizioni d'uso del sito prima di utilizzarlo
  • In qualità di Affiliato Amazon io ricevo un guadagno dagli acquisti idonei qualora siano presenti link al suddetto sito.

Permalink link a questo articolo: https://www.mauroalfieri.it/make/3d-support-vinpok.html

Lascia un commento

Il tuo indirizzo email non sarà pubblicato.

Questo sito usa Akismet per ridurre lo spam. Scopri come i tuoi dati vengono elaborati.